Arduino 스마트폰 블루투스 주행로봇 사용 하기
* Update history
- 2016.5.17 : 초기 Release
아두이노(Arduino) 디바이스를 이용해서 자신만의 장남감, 원격조정기, 로봇등의 많은 다른 흥미로운 프로젝트를 할수 있습니다.
기본적으로 검은색 라인 트레이싱이 가능한 주행 로봇 입니다. 스마트폰(안드로이드) 에서 블루투스 통신을 이용해서 아두이노 보드의 DC 모터를 제어하여 컨트롤도 할수 있습니다. L293D 모터 드라이버 IC를 사용하였습니다.
* 강의 전체 로드맵
I. 주행 로봇 조립하기
주행로봇의 모터, 초음파센서, 블루투스, 서보모터 등의 조립방법과 결선 방법에 대해서 설명 합니다.
1.1 DC 기어드 모터 준비
1.2 볼케스트, 바퀴 조립
1.3 배터리 박스 조립
1.4 아두이노 컨트롤 보드 조립
1.5 적외선 트레이싱 센서 조립
1.6 DC 초음파 센서 거치를 위한 서보 모터 조립
1.7 초음파 센서 조립
II. 주행로봇 응용
PC의 터미널을 통해서 명령으로 주행로봇의 DC모터를 제어하고, 블루투스를 통해 안드로이드 스마트폰에서 주행 로봇을 제어하는 방법에 대해서 설명 합니다.
또한 서보모터와 초음파 센서, 적외선 라인트레이싱 센서를 이용해서 검은색 라인을 따라가는 방법에 대해서도 설명 합니다.
2.1 아두이노 다운로더 USB 드라이버 설치
2.2 윈도 환경에서 드라이버 설치
2.3 주행로봇 아두이노 보드의 부위별 명칭
2.4 아두이노 컨트롤 보드와 모터 제어 배선 연결
2.5 아두이노 호환 보드 환경 설정
2.6 호환 보드 선택
2.7 L293D 모터 드라이버 IC
2.8 L293D 모터 드라이버 IC 사용 설명
2.9 DC 모터 제어 예제
2.10 아두이노 블루투스 통신
2.11 적외선 라이트레이싱
2.12 서보모터 제어
2.13 초음파 센서 제어
이 강의 자료에 대한 모든 질의사항은 http://cafe.naver.com/avrstudio 의 Arduino Q&A 게시판에 글을 남겨 주시거나 master@deviceshop.net 로 메일을 보내주시기 바랍니다. 가급적이면 여러 사람이 질문에 대한 답변을 공유 할수 있도록 네이버 카폐 게시판을 이용해 주셨으면 합니다. 감사합니다.
2.1 아두이노 다운로더 USB 드라이버 설치
USB 드라이버 다운로드 ( https://www.silabs.com/products/mcu/Pages/USBtoUARTBridgeVCPDrivers.aspx )
사용하시는 운영체제에 맞는 드라이버를 선택해서 다운로드후 설치 하세요.
2.2 윈도 환경에서 드라이버 설치
2.3 주행로봇 아두이노 보드의 부위별 명칭
- 왼쪽 모터의 붉은색 선을 십자드라이버를 이용해서
"왼쪽모터1 +(Red)"
"왼쪽모터1 -(Black)"
"왼쪽모터2 +(Red)"
"왼쪽모터2 -(Black)" 와 연결 합니다.
- 여기서 모터 결선을 잘못하면 스케치를 업로드 하고 테스트를 할때 모터가 반대로 동작 할 수 있습니다.
- 배터리 연결선도 마찬가지로
"배터리 박스에 연결된 붉은색 선을 "배터리(Red)+"
"배터리 박스에 연결된 검은색 선을 "배터리(Black)-" 와 연결 합니다.
- 나중에 주행 로봇 테스트를 할때는 전원공급, 충전 스위치를 "TAB" 위치로 해서 사용을 해야 합니다.
2.4 아두이노 컨트롤 보드와 모터 제어 배선 연결
- 모터 EA, EB 포트에 있는 점퍼는 제거 합니다.
2.5 아두이노 호환 보드 환경 설정
- 아두이노 개발환경에는 기본적으로 지원을 하지 않기 때문체 호환 보드를 추가하는 절차가 필요 합니다.
- 아래 절차대로 아두이노가 설치된 폴더의 boards.txt 파일을 변경해야 합니다.
-
- boards.txt 파일을 변경한다고 해서 아두이노 기본 보드들을 사용하지 못하는 것은 아니고, 호환 보드가 새로 추가만 되는 것입니다.
- 파일들을 텍스트 에디터로 열어서 비교해 보면 아두이노 기본 보드와 IO 포트의 갯수와 타이머 설정등이 다른것을 볼수 있습니다.
- linetracer.zip 파일 다운로드
2.6 호환 보드 선택
2.7 L293D 모터 드라이버 IC
2.8 L293D 모터 드라이버 IC 사용 설명
- 아두이노 보드의 모터 ENB가 Motor2 Enable핀 입니다.
- 더 자세한 설명은 아래 표를 참조하세요.
2.9 DC 모터 제어 예제
'F' - 왼쪽, 오른쪽 모터를 정방향 으로 회전
'B' - 왼쪽, 오른쪽 모터를 역방향 으로 회전
'L' - 왼쪽 모터를 정방향 으로 회전
'R' - 오른쪽 모터를 역방향 으로 회전
'S' - 왼쪽, 오른쪽 모터 정지
- DC모 터 제어 스케치 다운로드
#include <Servo.h>
Servo myservo;
int pos = 0; // variable to store the servo position
#define trigPin 11
#define echoPin 10
#define servoPin 13
// for Car
const int MOTO1_EN_PIN = 14; // Left wheel
const int MOTO2_EN_PIN = 15; // right wheel
int gbl_cur_motor_speed = 140; // motor speed
// 왼쪽 모터 회전 방향
const int I11_PIN = 16; // In1
const int I12_PIN = 17; // In2
// 오른쪽 모터 회전 방향
const int I21_PIN = 18; // In3
const int I22_PIN = 19; // In4
void setup() {
Serial.begin(9600);
delay(100);
myservo.attach(servoPin);
pinMode(MOTO1_EN_PIN, OUTPUT);
pinMode(MOTO2_EN_PIN, OUTPUT);
pinMode(I11_PIN, OUTPUT);
pinMode(I12_PIN, OUTPUT);
pinMode(I21_PIN, OUTPUT);
pinMode(I22_PIN, OUTPUT);
}
void car_forward(int moto_speed)
{
digitalWrite(I11_PIN, LOW);
digitalWrite(I12_PIN, HIGH);
digitalWrite(I21_PIN, LOW);
digitalWrite(I22_PIN, HIGH);
// motion
analogWrite(MOTO1_EN_PIN, moto_speed);
analogWrite(MOTO2_EN_PIN, moto_speed);
}
void car_backward(int moto_speed)
{
digitalWrite(I11_PIN, HIGH);
digitalWrite(I12_PIN, LOW);
digitalWrite(I21_PIN, HIGH);
digitalWrite(I22_PIN, LOW);
// motion
analogWrite(MOTO1_EN_PIN, moto_speed);
analogWrite(MOTO2_EN_PIN, moto_speed);
}
void car_left(int moto_speed)
{
digitalWrite(I21_PIN, LOW);
digitalWrite(I22_PIN, HIGH);
// motion
analogWrite(MOTO1_EN_PIN, 0);
analogWrite(MOTO2_EN_PIN, moto_speed);
}
void car_right(int moto_speed)
{
digitalWrite(I11_PIN, LOW);
digitalWrite(I12_PIN, HIGH);
// motion
analogWrite(MOTO1_EN_PIN, moto_speed);
analogWrite(MOTO2_EN_PIN, 0);
}
void car_stop()
{
digitalWrite(I11_PIN, LOW);
digitalWrite(I12_PIN, LOW);
digitalWrite(I21_PIN, LOW);
digitalWrite(I22_PIN, LOW);
// motion
analogWrite(MOTO1_EN_PIN, 0);
analogWrite(MOTO2_EN_PIN, 0);
}
/*
void serialEvent(){
char text = Serial.read();
Serial.print("data : ");
Serial.println(text);
}
*/
void loop()
{
int cmd ;
if( Serial.available() > 0 )
{
myservo.write(120);
cmd = Serial.read();
if( cmd == 'L' )
{
car_left(gbl_cur_motor_speed);
Serial.println("Left");
}
else if( cmd == 'R' )
{
car_right(gbl_cur_motor_speed);
Serial.println("Right");
}
else if( cmd == 'F' )
{
car_forward(gbl_cur_motor_speed);
Serial.println("Forward");
}
else if( cmd == 'B' )
{
car_backward(gbl_cur_motor_speed);
Serial.println("Backward");
}
else if( cmd == 'S' )
{
car_stop();
Serial.println("Stop");
}
}
delay(20);
}
2.10 아두이노 블루투스 통신
- 여기서는 이미 구글 플레이 스토어에 많이 올라와 있는 기본 앱을 사용하도록 할게요.
- 블루투스 제어 예제의 안드로이드 소스가 필요하신 분들은 master@deviceshop.net 메일로 요청을 해주시면 보내드릴게요.
- 대/소 문자를 구분을 하므로 반드시 대문자로 할당 하세요.
- DC모 터 제어 스케치 다운로드
2.11 적외선 라이트레이싱
- 아래 그림에서 센서가 검은색을 인식하면 아두이노 디지털 포트에 "HIGH" 가 된다고 했는데,
실제 테스트결과 "LOW" 가 맞는네요. 주의해서 스케치 코드를 보아야 할것 같습니다.
- 라 인트레이싱 스케치 다운로드
#define trigPin 11
#define echoPin 10
#define servoPin 13
#include <Servo.h>
Servo myservo;
int pos = 0; // variable to store the servo position
const int MOTO1_EN_PIN = 14; // Left wheel
const int MOTO2_EN_PIN = 15; // right wheel
// 왼쪽 모터 회전 방향
const int I11_PIN = 16; // In1
const int I12_PIN = 17; // In2
// 오른쪽 모터 회전 방향
const int I21_PIN = 18; // In3
const int I22_PIN = 19; // In4
// int MOTO_SPEED = 110;
int MOTO_SPEED_L = 50;
int MOTO_SPEED_R = 50;
int MOTO_SPEED = 150;
int MOTO_SPEED_L1 = MOTO_SPEED-30;
int MOTO_SPEED_L2 = MOTO_SPEED-50;
int IR_L = 3; // 왼쪽 적외선 센서
int IR_M = 4; // 가운데 적외선 센서
int IR_R = 5; // 오른쪽 적외선 센서
int last_status = 'S';
void setup() {
Serial.begin(9600);
delay(100);
myservo.attach(servoPin);
pinMode(MOTO1_EN_PIN, OUTPUT);
pinMode(MOTO2_EN_PIN, OUTPUT);
pinMode(I11_PIN, OUTPUT);
pinMode(I12_PIN, OUTPUT);
pinMode(I21_PIN, OUTPUT);
pinMode(I22_PIN, OUTPUT);
}
void car_forward(int moto_speed)
{
digitalWrite(I11_PIN, LOW);
digitalWrite(I12_PIN, HIGH);
digitalWrite(I21_PIN, LOW);
digitalWrite(I22_PIN, HIGH);
// motion
analogWrite(MOTO1_EN_PIN, moto_speed);
analogWrite(MOTO2_EN_PIN, moto_speed);
delay(10);
}
void car_lf_rf(int moto_speed_left, int moto_speed_right)
{
// car_stop();
// left wheel
digitalWrite(I11_PIN, LOW);
digitalWrite(I12_PIN, HIGH);
// right wheel
digitalWrite(I21_PIN, LOW);
digitalWrite(I22_PIN, HIGH);
// motion
analogWrite(MOTO1_EN_PIN, moto_speed_left);
analogWrite(MOTO2_EN_PIN, moto_speed_right);
}
void car_stop()
{
digitalWrite(I11_PIN, LOW);
digitalWrite(I12_PIN, LOW);
digitalWrite(I21_PIN, LOW);
digitalWrite(I22_PIN, LOW);
// motion
analogWrite(MOTO1_EN_PIN, 0);
analogWrite(MOTO2_EN_PIN, 0);
}
void loop()
{
int r,m,l;
myservo.write(128);
r = digitalRead(IR_R);
m = digitalRead(IR_M);
l = digitalRead(IR_L);
// LOW일때 검은색이 검출된다.
if((l==HIGH) && (m==LOW) && (r==HIGH))
{
car_forward(MOTO_SPEED);
//retry = 0;
}
else if((l==LOW) && (m==LOW) && (r==LOW))
{
car_forward(MOTO_SPEED);
//retry = 0;
}
else if((l==LOW) && (m==HIGH) && (r==HIGH))
{
// car_left(MOTO_SPEED);
car_lf_rf(MOTO_SPEED_L2, MOTO_SPEED);
last_status = 'L';
//retry = 0;
Serial.println("Right");
}
else if((l==LOW) && (m==LOW) && (r==HIGH))
{
car_lf_rf(MOTO_SPEED_L1, MOTO_SPEED);
last_status = 'L';
//retry = 0;
Serial.println("Left");
}
else if((l==HIGH) && (m==HIGH) && (r==LOW))
{
//car_right(MOTO_SPEED);
car_lf_rf(MOTO_SPEED, MOTO_SPEED_L2);
last_status = 'R';
//retry = 0;
Serial.println("Right");
}
else if((l==HIGH) && (m==LOW) && (r==LOW))
{
car_lf_rf(MOTO_SPEED, MOTO_SPEED_L1);
last_status = 'R';
//retry = 0;
Serial.println("Right");
}
else if((l==HIGH) && (m==HIGH) && (r==HIGH))
{
car_stop();
}
// delay(2);
}
2.12 서보모터 제어
- 서보 모터 스케치 다운로드
#include <Servo.h>
#define servoPin 13
Servo myservo;
int pos = 0; // variable to store the servo position
void setup()
{
myservo.attach(servoPin); // attaches the servo on pin 9 to the servo object
}
void loop()
{
for(pos = 0; pos < 180; pos += 1) // goes from 0 degrees to 180 degrees
{ // in steps of 1 degree
myservo.write(pos); // tell servo to go to position in variable 'pos'
delay(15); // waits 15ms for the servo to reach the position
}
for(pos = 180; pos>=1; pos-=1) // goes from 180 degrees to 0 degrees
{
myservo.write(pos); // tell servo to go to position in variable 'pos'
delay(15); // waits 15ms for the servo to reach the position
}
}
2.13 초음파 센서 제어
- 초음 파센서 제어 스케치 다운로드
#define trigPin 11
#define echoPin 10
#define servoPin 13
#include <Servo.h>
Servo myservo;
int pos = 0; // variable to store the servo position
void setup()
{
Serial.begin (9600);
pinMode(trigPin, OUTPUT);
pinMode(echoPin, INPUT);
myservo.attach(servoPin);
}
long microsecondsToCentimeters(long microseconds)
{
return microseconds / 29 / 2;
}
int GetCentiMeter()
{
long duration, cm;
digitalWrite(trigPin, LOW);
delayMicroseconds(2);
digitalWrite(trigPin, HIGH);
delayMicroseconds(10);
digitalWrite(trigPin, LOW);
duration = pulseIn(echoPin, HIGH);
// convert the time into a distance
cm = microsecondsToCentimeters(duration);
return cm;
}
void loop()
{
long cm;
for(pos = 0; pos < 180; pos += 1) // goes from 0 degrees to 180 degrees
{ // in steps of 1 degree
myservo.write(pos); // tell servo to go to position in variable 'pos'
cm = GetCentiMeter();
Serial.print(cm);
Serial.println(" cm");
}
for(pos = 180; pos>=1; pos-=1) // goes from 180 degrees to 0 degrees
{
myservo.write(pos); // tell servo to go to position in variable 'pos'
cm = GetCentiMeter();
Serial.print(cm);
Serial.println(" cm");
}
}
여기까지 주행 로봇 제어를 위한 배선도와 예제 코드를 살펴 보았습니다. 추가로 질문사항이나 요청 사항이 있으시면
http://cafe.naver.com/avrstudio 나 master@deviceshop.net 로 문의해 주세요.
즐 아두이노 하세요.. ㅋ